patos/pkgs/dbus-broker/default.nix

{
  stdenv,
  pkgs,
  ...
}:

stdenv.mkDerivation (finalAttrs: {
  pname = "dbus-broker";
  version = pkgs.dbus-broker.version;

  src = pkgs.dbus-broker.src;

  nativeBuildInputs = pkgs.dbus-broker.nativeBuildInputs;
  buildInputs = pkgs.dbus-broker.buildInputs;

  mesonFlags = [
    # while we technically support 4.9 and 4.14, the NixOS module will throw an
    # error when using a kernel that's too old
    "--prefix=/"
    "--bindir=/usr/bin"
    "-D=linux-4-17=true"
    "-D=system-console-users=gdm,sddm,lightdm"
  ];

  PKG_CONFIG_SYSTEMD_SYSTEMDSYSTEMUNITDIR = "/usr/lib/systemd/system";
  PKG_CONFIG_SYSTEMD_SYSTEMDUSERUNITDIR = "/usr/lib/systemd/user";
  PKG_CONFIG_SYSTEMD_CATALOGDIR = "/usr/lib/systemd/catalog";

  preInstall = ''
    export DESTDIR=${placeholder "out"}
  '';

  postInstall = ''
    mkdir -p $out/usr/share
    cp -Pr ${pkgs.dbus.out}/share/* $out/usr/share/
    cp ${pkgs.dbus.out}/etc/systemd/system/dbus.socket $out/usr/lib/systemd/system/
    mv $out/usr/lib/systemd/system/dbus-broker.service $out/usr/lib/systemd/system/dbus.service
    find $out/usr/share/ -type d -exec chmod 755 {} \;
    sed -i 's#/nix/store.*/share#/usr/share#' $out/usr/share/xml/dbus-1/catalog.xml
    sed -i 's#/nix/store.*/libexec#/usr/bin#' $out/usr/share/dbus-1/system.conf

    mkdir -p $out/usr/lib/sysusers.d/
    echo 'u! messagebus - "DBus broker"' > $out/usr/lib/sysusers.d/dbus-broker.conf
  '';

  doCheck = false;

  meta = pkgs.dbus-broker.meta;
})